IntelliJ-IdeaVim/build.gradle

buildscript {
  repositories {
    mavenCentral()
  }

  dependencies {
    classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"
  }
}

plugins {
  id 'org.jetbrains.intellij' version '0.4.16'
}

apply plugin: 'java'
apply plugin: 'kotlin'

sourceCompatibility = javaVersion
targetCompatibility = javaVersion

tasks.withType(JavaCompile) { options.encoding = 'UTF-8' }

sourceSets {
  main {
    java.srcDir 'src'
    resources.srcDir 'resources'
  }
  test {
    java.srcDir 'test'
  }
}

intellij {
  version ideaVersion
  pluginName 'IdeaVim'
  updateSinceUntilBuild false
  downloadSources Boolean.valueOf(downloadIdeaSources)
  instrumentCode Boolean.valueOf(instrumentPluginCode)
  intellijRepo = "https://www.jetbrains.com/intellij-repository"
  if (!Boolean.valueOf(legacyNoJavaPlugin)) {
    // Since 192 version of IJ java plugin should be defined separately
    // Set `legacyNoJavaPlugin` to true if you are going to run tests under idea version < 192
    plugins = ['java']
  }

  publishPlugin {
    channels publishChannels.split(',')
    username publishUsername
    token publishToken
  }
}

repositories {
  mavenCentral()
}

dependencies {
  compileOnly "org.jetbrains.kotlin:kotlin-stdlib-jdk8:$kotlinVersion"
  compileOnly "org.jetbrains:annotations:19.0.0"
}

compileKotlin {
  kotlinOptions {
    jvmTarget = javaVersion
  }
}
compileTestKotlin {
  kotlinOptions {
    jvmTarget = javaVersion
  }
}

tasks.register("slackEapNotification") {
  doLast {
    if (!slackUrl) return
    def post = new URL(slackUrl).openConnection()
    def changeLog = extractChangelog()
    changeLog = changeLog.replace("* ", "• ") // Replace stars with bullets
    changeLog = changeLog.replace("**", "*") // Enable bold text
    changeLog = changeLog.replaceAll("\\[(.+)]\\(([^)]+)\\)", '<$2|$1>') // Enable links
    def message ="""
      {
          "text": "Danny Torrence left a 1 star review for your property.",
          "blocks": [
                  {
                    "type": "section",
                    "text": {
                      "type": "mrkdwn",
                      "text": "New EAP released: $version\\n$changeLog"
                    }
                  }
          ]
      }
   """
    post.setRequestMethod("POST")
    post.setDoOutput(true)
    post.setRequestProperty("Content-Type", "application/json")
    post.getOutputStream().write(message.getBytes("UTF-8"))
    def postRC = post.getResponseCode()
    println(postRC)
    if(postRC == 200) {
      println(post.getInputStream().getText())
    }
  }
}

// Very primitive changelog extraction code
def extractChangelog() {
  def startLine = "_Available since $version EAP:_"
  def endLine = "_To Be Released..._"
  def startSaving = false
  def res = new StringBuilder()
  new File("./CHANGES.md").eachLine { line ->
    if (startSaving) {
      if (line == endLine) {
        startSaving = false
      }
      else {
        res.append(line).append('\n')
      }
    }
    else {
      if (line == startLine) {
        startSaving = true
      }
    }
  }
  return res.toString()
}